Formatierung eines CellRange auf ein anderes CellRange übertragen

[Cepheus]

Besten Dank, mikele!
Jawohl, das funktioniert jetzt. Hier wiederhole ich deine Empfehlung als Ganzes:

Dim oRanges
oRanges = ThisComponent.createInstance("com.sun.star.sheet.SheetCellRanges")
ThisComponent.CurrentController.Select(oRanges)
dispatcher.executeDispatch(document, ".uno:SetInputMode", "", 0, Array())
dispatcher.executeDispatch(document, ".uno:Cancel", "", 0, Array())

Gruß,
Cepheus

[mikele]

Hallo,
ich habe mal etwas weiter geknobelt, um das Problem per API (ohne Dispatcher zu lösen).
Dazu ist es wohl notwendig alle relevanten Eigenschaften einzeln zu übertragen.

Code: Alles auswählen

Sub Main
	'Eigenschaften der Zellen, die übertragen werden sollen, es gibt noch mehr ...
	eigenschaften=Array("CellStyle", "CellBackColor", "IsCellBackgroundTransparent", "HoriJustify", "VertJustify", "IsTextWrapped",_
	"ParaIndent", "Orientation", "RotateAngle", "RotateReference", "TableBorder", "TopBorder", "BottomBorder",_
	"LeftBorder", "RightBorder", "NumberFormat", "ShadowFormat", "CellProtection", "DiagonalTLBR", "DiagonalBLTR",_
	"TableBorder2", "TopBorder2", "BottomBorder2", "LeftBorder2", "RightBorder2", "DiagonalTLBR2", "DiagonalBLTR2",_
	"CharColor", "CharFontName", "CharHeight", "CharPosture", "CharWeight")
	'Zugriff auf Dokument
	oDoc=ThisComponent
	'Zugriff auf 1. Tabelle
	oTab=oDoc.Sheets(0)
	'der einzeilige Quellbereich
	quelle=oTab.getCellrangeByName("C3:I3")
	spalten=quelle.Columns.Count
	'der mehrzeilige Zielbereich gleicher Breite
	ziel=oTab.getCellrangeByName("C7:I10")
	zeilen=ziel.Rows.Count
	'Durchlauf durch alle Spalten des Zielbereichs
	for spalte=0 to n-1
		'Erfassen und Übertragen der bedingten Formatierung
		bedformat=quelle.getCellByPosition(spalte,0).ConditionalFormat
		ziel.getCellRangeByPosition(spalte,0,spalte,zeilen-1).ConditionalFormat=bedformat
		'Erfassen und Übertragen der weiteren Eigenschaften
		for i=0 to ubound(eigenschaften)
			tmp=quelle.getCellByPosition(spalte,0).getPropertyValue(eigenschaften(i))
			ziel.getCellRangeByPosition(spalte,0,spalte,zeilen-1).setPropertyValue(eigenschaften(i),tmp)
		next
	next
End Sub

[Cepheus]

Hallo, mikele,
zunächst wieder einmal danke für deine Lösungssuche.
Ich habe deinen Code in meinem mit Option Explicit versehenen Modul adaptiert. Aber die Codezeile

ziel.getCellRangeByPosition(spalte,0,spalte,zeilen-1).setPropertyValue(eigenschaften(i),tmp)

erzeugt eine IllegalArgumentException. Was kann ich tun?
Ich schicke dir den adaptierten Code.

Code: Alles auswählen

Die zugehörige Testdatei hast du schon bekommen.
Gruß,
Cepheus

[mikele]

Hallo,
es war auch noch ein grober Fehler (das kommt davon, wenn man im Nachhinein die Variablen ändert )
Nun mit option explicit:

Code: Alles auswählen

option explicit

Sub Main
	dim eigenschaften, bedformat, tmp
	dim odoc as object, otab as object, quelle as object, ziel as object
	dim spalten as integer, zeilen as integer, i as integer, spalte as integer
	'Eigenschaften der Zellen, die übertragen werden sollen, es gibt noch mehr ...
	eigenschaften=Array("CellStyle", "CellBackColor", "IsCellBackgroundTransparent", "HoriJustify", "VertJustify", "IsTextWrapped",_
	"ParaIndent", "Orientation", "RotateAngle", "RotateReference", "TableBorder", "TopBorder", "BottomBorder",_
	"LeftBorder", "RightBorder", "NumberFormat", "ShadowFormat", "CellProtection", "DiagonalTLBR", "DiagonalBLTR",_
	"TableBorder2", "TopBorder2", "BottomBorder2", "LeftBorder2", "RightBorder2", "DiagonalTLBR2", "DiagonalBLTR2",_
	"CharColor", "CharFontName", "CharHeight", "CharPosture", "CharWeight")
	'Zugriff auf Dokument
	oDoc=ThisComponent
	'Zugriff auf 1. Tabelle
	oTab=oDoc.Sheets(0)
	'der einzeilige Quellbereich
	quelle=oTab.getCellrangeByName("C3:I3")
	spalten=quelle.Columns.Count
	'der mehrzeilige Zielbereich gleicher Breite
	ziel=oTab.getCellrangeByName("C7:I10")
	zeilen=ziel.Rows.Count
	'Durchlauf durch alle Spalten des Zielbereichs
	for spalte=0 to spalten-1
		'Erfassen und Übertragen der bedingten Formatierung
		bedformat=quelle.getCellByPosition(spalte,0).ConditionalFormat
		ziel.getCellRangeByPosition(spalte,0,spalte,zeilen-1).ConditionalFormat=bedformat
		'Erfassen und Übertragen der weiteren Eigenschaften
		for i=0 to ubound(eigenschaften)
			msgbox eigenschaften(i)
			tmp=quelle.getCellByPosition(spalte,0).getPropertyValue(eigenschaften(i))
			ziel.getCellRangeByPosition(spalte,0,spalte,zeilen-1).setPropertyValue(eigenschaften(i),tmp)
		next
	next
End Sub

[Cepheus]

Hallo, mikele!
Super, jetzt funktioniert es also auch per API.

Ja, das Thema hat den großen Unterschied zwischen einem Experten und einem grünen Anfänger aufgezeigt! (Der Letztere bin nämlich ich.) Oh, ich könnte eine Menge Sachen von dir lernen!

Ich könnte dir nicht genug danken,
Gruß,
Cepheus