Seite 1 von 1
Teile aus vielen Dokumenten in einem zusammenfassen
Verfasst: Fr 8. Nov 2013, 16:52
von Phren
Hallo in die Runde,
ich möchte gerne Teile aus einem ganzen Haufen von Dokumenten in einem zusammenfassen. Zunächst habe ich Code geschrieben der ein Teil aus einem Dokument in ein anderes Dokument kopiert:
Code: Alles auswählen
Sub Main
' Quelle öffnen
Quelle = "input.ods"
QuellenUrl = converttourl(Quelle)
QuellDokument = StarDesktop.loadComponentFromURL (QuellenUrl,"_blank", 0, Array())
' Ziel öffnen
ZielUrl = "private:factory/scalc"
ZielDokument = StarDesktop.loadComponentFromURL (ZielUrl, "_blank", 0, Array())
' Quellbereich auswählen
QuellDokumentRange = QuellDokument.Sheets(0).getCellRangeByName("A15:H54")
QuellDokumentRangeAddresse = QuellDokumentRange.getRangeAddress
' Zielbereich wählen
ZielDokumentRange = ZielDokument.Sheets(0).getCellByPosition(2,5)
ZielDokumentRangeAddresse = ZielDokumentRange.GetRangeAddress
' Kopieren
ZielDokument.Sheets(0).copyRange(ZielDokumentRangeAddresse, QuellDokumentRangeAddresse)
End Sub
Allerdings wie bei
StarBasic / OpenOffice.org Basic FAQ angegeben, funktioniert das nicht: "cannot coerce argument type during corerefection call!". Ich nehme das es sich dabei um die entsprechende Fehlermeldung handelt.
Meine Frage ist wie ich Teile aus meheren Dokumenten in einem zusammenfassen kann?
Vielen Dank!
--
Phren
Re: Teile aus vielen Dokumenten in einem zusammenfassen
Verfasst: Fr 8. Nov 2013, 17:15
von balu
Hallo Phren,
wenn Du nur aus verschiedenen Calc-Dateien in eine Calc-Datei kopieren willst, dann versuchs mal hiermit.
Code: Alles auswählen
Sub Main
' Quelle öffnen
Quelle = "input.ods"
QuellenUrl = converttourl(Quelle)
QuellDokument = StarDesktop.loadComponentFromURL (QuellenUrl,"_blank", 0, Array())
' Ziel öffnen
ZielUrl = "private:factory/scalc"
ZielDokument = StarDesktop.loadComponentFromURL (ZielUrl, "_blank", 0, Array())
dim aDatArray()
aDatArray = QuellDokument.Sheets(0).getCellRangeByName("A15:H54").getDataArray 'Quelle
ZielDokument.Sheets(0).getCellByPosition(2,5).setDataArray(aDatArray) ' Ziel
End Sub
Du musst allerdings bei Quelle nicht nur den Dateinamen, sondern auch noch den Pfad mit angeben. Sonst wird das nix.
Gruß
balu
Re: Teile aus vielen Dokumenten in einem zusammenfassen
Verfasst: Mo 11. Nov 2013, 09:59
von Phren
Hallo,
bei mir funktioniert es nur wenn ich den genauen Range angebe:
Code: Alles auswählen
Sub Main
dim aDataArray as Object
' Quelle öffnen
Quelle = "/home/hw/Documents/Stunden/2013/Stundenzettel_HW_03_2013.ods"
QuellenUrl = converttourl(Quelle)
QuellDokument = StarDesktop.loadComponentFromURL (QuellenUrl,"_blank", 0, Array())
' Ziel öffnen
ZielUrl = "private:factory/scalc"
ZielDokument = StarDesktop.loadComponentFromURL (ZielUrl, "_blank", 0, Array())
aDataArray = QuellDokument.Sheets(0).getCellRangeByName("A15:H54").getDataArray() 'Quelle
ZielDokument.Sheets(0).getCellRangeByName("A15:H54").setDataArray(aDataArray) ' Ziel
End Sub
Ich bekomme sonst eine Exception und zwar wie es beschrieben ist:
interface XCellRangeData
"getCellByPosition(0,0).setDataArray(aDataArray)" wäre mir zwar lieber aber so geht es auch.
Vielen Dank für Deine Hilfe.
Gruss,
--
Phren
Re: Teile aus vielen Dokumenten in einem zusammenfassen
Verfasst: Mo 11. Nov 2013, 10:19
von karolus
Hallo
Die Dimensionen deines Zellbereichs kannst du berechnen:
Code: Alles auswählen
Sub Main
doc = thisComponent
sheet = doc.sheets(0)
data = array(array(1,2,3),array(4,5,6))
s = 2 'index Spalte C
r = 4 'index Zeile 5
z_count = ubound(data)
c_count = ubound( data(0) )
range = sheet.getCellrangebyPosition(s, r, s+c_count, r+z_count)
range.setDataArray( data )
End Sub
Karolus
Re: Teile aus vielen Dokumenten in einem zusammenfassen
Verfasst: Mo 11. Nov 2013, 12:52
von balu
Hallo Phren,
sorry, hatte diesen Teil leider falsch angegeben.
Hast es aber selbst hinbekommen. Prima.
Gruß
balu