Seite 1 von 1
Ausblenden aller Symbolleisten
Verfasst: So 17. Nov 2013, 21:12
von arkadiuszpaluszek
Hallo!
Ich versuche mit folgendem Skript ALLE Symbolleisten und sonstige Elemente auszuiblenden, um am Ende nur ein "leeres" Fenster mit ein paar Buttons zu haben:
Code: Alles auswählen
Sub Main
dim oDoc as Object, oFrame as Object, oWin as Object, oLayoutManager as Object
oDoc=thisComponent
oFrame=oDoc.CurrentController.Frame
oLayoutManager=oFrame.LayoutManager
oLayoutManager.setVisible(False)
oWin=oFrame.GetContainerWindow()
' Werte: X,Y, Länge, Höhe
oWin.setPosSize(50,50,880,80,15)
End Sub
Auf dem Mac klappt es wunderbar, unter Windows 7 habe ich allerdings noch das etwas störende Lineal:
- bild.jpg (48.85 KiB) 4625 mal betrachtet
Habe ich eigentlich einen Fehler im Code oder ist es ein Fehler von LibreOffice?
Gruß
Arek
Re: Ausblenden aller Symbolleisten
Verfasst: So 17. Nov 2013, 22:03
von F3K Total
Hi,
dies sollte funktionieren:
Code: Alles auswählen
Sub S_small_window_hide_ruler
dim oDoc as Object, oFrame as Object, oWin as Object, oLayoutManager as Object
oDoc = thisComponent
ocontroller = oDoc.currentController
with oController.Viewsettings
.setPropertyValue("ShowVertRuler",false)
.setPropertyValue("ShowHoriRuler",false)
end with
oFrame = ocontroller.Frame
oLayoutManager = oFrame.LayoutManager
oLayoutManager.setVisible(False)
oWin = oFrame.GetContainerWindow()
' Werte: X,Y, Länge, Höhe
oWin.setPosSize(50,50,880,80,15)
End Sub
Gruß R
Re: Ausblenden aller Symbolleisten
Verfasst: So 17. Nov 2013, 22:28
von arkadiuszpaluszek
Ja, es hat funktioniert, herzlichen Dank mal wieder!
Re: Ausblenden aller Symbolleisten
Verfasst: So 17. Nov 2013, 22:40
von F3K Total
Hi,
noch eine kleine Verbesserung um auch die Scrollbars auszublenden:
Code: Alles auswählen
with oController.Viewsettings
.setPropertyValue("ShowHoriRuler",false)
.setPropertyValue("ShowVertRuler",false)
.setPropertyValue("ShowHoriScrollBar",false)
.setPropertyValue("ShowVertScrollBar",false)
end with
Gruß R
Re: Ausblenden aller Symbolleisten
Verfasst: Mo 25. Nov 2013, 16:38
von arkadiuszpaluszek
Danke!
Re: Ausblenden aller Symbolleisten
Verfasst: Fr 6. Dez 2013, 17:11
von arkadiuszpaluszek
Und wie funktioniert es dann eigentlich beim Calc? Da bekomme ich dann die Meldung "Eigenschaft oder Methode nicht gefunden: Viewsettings".
Re: Ausblenden aller Symbolleisten
Verfasst: Fr 6. Dez 2013, 17:26
von F3K Total
So z.B.:
Code: Alles auswählen
sub Test
ocontroller = thiscomponent.currentController
with ocontroller
.ColumnRowHeaders = False
.FirstVisibleColumn = 2 'Spalte C
.FirstVisibleRow = 2 'Zeile 3
.HorizontalScrollBar = false
.VerticalScrollBar =false
.SheetTabs = false
.ZoomValue = 75
end with
end sub
sub Test_Reset
ocontroller = thiscomponent.currentController
with ocontroller
.ColumnRowHeaders = True
.FirstVisibleColumn = 0 'Spalte C
.FirstVisibleRow = 0 'Zeile 3
.HorizontalScrollBar = True
.VerticalScrollBar = true
.SheetTabs = true
.ZoomValue = 100
end with
end sub
Gruß R