Seite 1 von 1
(gelöst) Wertübernahme von Formular zu Formular
Verfasst: Mi 14. Nov 2018, 13:13
von PeterF
Hallo Leute,
ich steck schon wieder fest.
Mit dem folgenden Makro möchte ich, dass die Kundennummer, die ich im Formular 'Kunden-Management' ausgewählt habe, beim Öffnen des Formulars 'Bestellungen-Test' in dessen Steuerungselement 'KundenTest' (Listbox) eingetragen wird.
Das ist erst einmal nicht kompliziert, doch möchte ich dabei, dass die ListSource der ListBox auf diese eine Kundennummer reduziert wird und der entsprechende Kunde mit seiner Adresse in einem Grid-Control angezeigt wird:
Code: Alles auswählen
Sub Kundenmanagment_Bestellung
Dim iKundenID As Long
Dim stSQL(0) As String
Dim oFeld, oForm As Object
oForm = ThisComponent.drawpage.forms.getByName("MainForm")
iKundenID = oForm.getByName("fmtINDEX").BoundField.getString
'msgbox "Kundennummer: " & iKundenID
stSQL(0) = "SELECT ""KundenID"" FROM ""Kunden"" WHERE ""KundenID"" = " &iKundenID
'thisDatabaseDocument.FormDocuments.getByName("Kunden-Managment").close
oFormDocBestell = thisDatabaseDocument.FormDocuments.getByName("Bestellungen-Test").Open
wait(1000)
oFormBestell = oFormDocBestell.drawpage.forms.getByName("FormBestell")
oFeldKunde = oFormBestell.getByName("KundenTest")
oSubKundenForm = oFormBestell.getByName("KundenForm")
oFeldKunde.ListSource = stSQL
oFeldKunde.refresh()
oDocCtl = ThisComponent.getCurrentController()
oElementKT = oFormBestell.getByName("KundenTest")
'oElementKTView = oDocCtl.getControl(oElementKT)
oFormBestell.reload()
StarDesktop.CurrentComponent.CurrentController.getControl(oElementKT).SelectItem(iKundenID,True)
'StarDesktop.CurrentComponent.CurrentController.getControl(oElementKT).SelectItem(iKundenID,False)
oSubKundenForm.reload()
oFormBestell.reload()
End Sub
Das Öffnen des Formulars und das Reduzieren des Inhaltes des ListBox funktioniert wie gewünscht.
Nur gelingt mir nicht, den einen Eintrag in der ListBox (Kundennummer) automatisch auszuwählen, damit ich das Grid-Control auf die Adreßinformationen des Kunden updaten kann.
Die Zeile
StarDesktop.CurrentComponent.CurrentController.getControl(oElementKT).SelectItem(iKundenID,True)
sollte eigentlich das erwünschte Ergebnis erzielen - dachte ich wenigstens.
Hat jemand eine zündende Idee
Danke im Voraus
Peter
Re: Wertübernahme von Formular zu Formular
Verfasst: Mi 14. Nov 2018, 17:42
von F3K Total
Hallo,
versuche mal dieses:
Code: Alles auswählen
Sub Kundenmanagment_Bestellung
Dim iKundenID As Long
Dim stSQL(0) As String
Dim oFeld, oForm As Object
oForm = ThisComponent.drawpage.forms.getByName("MainForm")
iKundenID = oForm.getByName("fmtINDEX").BoundField.getString
'msgbox "Kundennummer: " & iKundenID
stSQL(0) = "SELECT ""KundenID"" FROM ""Kunden"" WHERE ""KundenID"" = " &iKundenID
'thisDatabaseDocument.FormDocuments.getByName("Kunden-Managment").close
oFormDocBestell = thisDatabaseDocument.FormDocuments.getByName("Bestellungen-Test").Open
wait(1000)
oFormBestell = oFormDocBestell.drawpage.forms.getByName("FormBestell")
oFeldKunde = oFormBestell.getByName("KundenTest")
oSubKundenForm = oFormBestell.getByName("KundenForm")
oFeldKunde.ListSource = stSQL
oFeldKunde.refresh()
oDocCtl = oFormDocBestell.getCurrentController()
oDocCtl.getControl(oFeldKunde).SelectItem(iKundenID,True)
End Sub
Ich denke, da du die iKundenID nicht speicherst, ist sie zwar kurz da, wird aber mit dem .reload des Formulares wieder gelöscht.
Gruß R
Re: Wertübernahme von Formular zu Formular
Verfasst: Mi 14. Nov 2018, 19:18
von PeterF
Hallo R,
das ist bisher das beste Ergebnis - ohne Fehlermeldung wird die Kundennummer in die Bestellungsformular eingetragen.
Super. Danke.
Als nächster Schritt sollte nun das Grid-Control die Adreßinfo der Kundennummer aktualisieren.
D.h. 'händisch' gehe ich im Formular "Bestellungen-Test"
- auf die ListBox "KundenTest" und wähle noch einmal die eingetragene Kundennummer aus
- Wähle in der Formular-Navigation 'Aktualisieren'
- Quittiere die Warnung 'Der Inhalt des aktuellen Formulars wurde geändert. Sollen die Änderungen gespeichert werden?' mit Ok
Wie bekomme ich die 3 Punkte automatisch hin?
Gruß
Peter
Re: Wertübernahme von Formular zu Formular
Verfasst: Do 15. Nov 2018, 17:04
von F3K Total
Sorry,
aber aus meiner Sicht bist du da falsch unterwegs, ein Listenfeld kann schon die Kundendaten anzeigen und die ID schreiben.
Lade ein Beispieldokument hoch, dann kann dir eher geholfen werden.
Gruß R
Re: Wertübernahme von Formular zu Formular
Verfasst: Do 15. Nov 2018, 19:30
von PeterF
Hallo R,
da ist meine bisherige Programmierung.
Ist noch nicht aufgeräumt - doch vieles funktioniert schon...
Unter Formulare "Kunden-Management" öffnen, einen Kunden aussuchen (falsche Namen und Tel.-nummern, aber existierende Adressen), der Button "weiter zur Bestellung" öffnet das Formular "Bestellungen-Test".
Hier wird im Feld "Kunden-Test" die KundenID (über die Variable iKundenID) eingetragen und ausgewählt.
Was mir jetzt fehlt, ist dass das Tabellen-Kontrollfeld "tab_Kunden" nun für die ausgesuchte KundenID die entsprechenden Kundeninfos so aktualisiert, dass die oben erwähnten 3 Schritte entfallen.
Am Tabellen-Kontrollfeld rechts unten (tab_Bestellung) kann ich dann erkennen, ob es erfolgreich war, da es mit der Tabelle "Bestellungen" verbunden ist. Hier muss die neue KundenID auftauchen.
Das Zahlen-Pad in der Mitte funktioniert auch schon - ist für eine Touch-Pad-Eingabe gedacht.
Das "<-X" löscht die letzte Zahl der SpeisenID, "Zero" setzt sie auf Null. Buchstaben sind nötig, da mancher Artikel mit einem solchem anfängt.
Vielleicht ist es leichter, als es aussieht.
Vielen Dank im Voraus
Peter
Re: Wertübernahme von Formular zu Formular
Verfasst: Do 15. Nov 2018, 21:49
von F3K Total
Es ist zu spät für lange Erklärungen, versuche es selbst zu verstehen.
Code: Alles auswählen
Sub Kundenmanagment_Bestellung
Dim iKundenID As Long
Dim oFeld, oForm As Object
oForm = ThisComponent.drawpage.forms.getByName("MainForm")
iKundenID = oForm.columns.KundenID.getint 'Kunden_ID auslesen
oFormDocBestell = thisDatabaseDocument.FormDocuments.getByName("Bestellungen-Test").Open
oFormBestell = oFormDocBestell.drawpage.forms.getByName("FormBestell")
do
wait 100
loop until oFormBestell.isloaded
oFormBestell.movetoinsertrow'neuer Datensatz
oFormBestell.columns.Kunden_ID.updateint(iKundenID)'Kunden_ID eintragen
if oFormBestell.isnew then oFormBestell.insertRow else oFormBestell.updaterow'Datensatz speichern
End Sub
Nur eines: Ich habe der Datenbank per Extras/SQL...
Code: Alles auswählen
ALTER TABLE "Bestellungen" ALTER "Bestelldatum" SET DEFAULT CURRENT_TIMESTAMP
mitgeteilt, dass sie den aktuellen Zeitstempel als Bestelldatum automatisch einträgt.
Gruß R
Re: Wertübernahme von Formular zu Formular
Verfasst: Do 15. Nov 2018, 23:25
von PeterF
Hey R,
Direkt in die "Bestellungen" einzufügen, ist garantiert die beste Lösung.
Hatte ich auch mal kurz angepeilt - bin in meinem Ansatz halt stecken geblieben.
Probiere ich morgen sofort aus.
Danke Dir für Deine Mühe.
Gruß
Peter
Re: Wertübernahme von Formular zu Formular
Verfasst: Fr 16. Nov 2018, 14:23
von F3K Total
hatte ganz vergessen die geänderte Datei hochzuladen ...
Re: Wertübernahme von Formular zu Formular
Verfasst: Fr 16. Nov 2018, 22:42
von PeterF
Hey, danke.
Die geänderte Datei funktioniert einwandfrei.
Super!!!