LibreOffice-Forum

Code: Alles auswählen

REM  *****  BASIC  *****
Sub ManipulateAnnotations
  Dim doc As Object
  Dim aSheet As Object
  Dim aCell As Object
  Dim annotations As Object
  Dim myAnnotation As Object
  
  doc = ThisComponent
  aSheet = doc.sheets.getByIndex(0)
  
  'Fügt einen neuen Kommentar ein.
  aCell = aSheet.getCellByPosition(0, 0)
  annotations = aSheet.annotations
  annotations.insertNew(aCell.cellAddress, "Textinhalt")
  
  'Ändert einen vorhandenen Kommentar.
  'Die Pseudo-Eigenschaft "annotation" der Zelle kann nur gelesen werden.
  myAnnotation = getAnnotationByCell(aCell)
  myAnnotation.isVisible = true
  myAnnotation.annotationShape.fillColor = rgb(250, 250,0)
  myAnnotation.annotationShape.charFontName = "Tahoma"
  myAnnotation.annotationShape.charHeight = 12

' Es wird ein neues Objekt deklariert 
dim sAnnoSize as new com.sun.star.awt.Size
sAnnoSize.Height= 2500						' Höhe
sAnnoSize.Width= 3500						' Breite
myAnnotation.annotationShape.size=sAnnoSize			' Zuweisung der Objekteigenschaft an das Shape
' xray sAnnoSize
	
' Beschreibung der möglichen Konstanten, wie sich der Text, bsz. das Kommentarfeld verhält.
' https://www.openoffice.org/api/docs/common/ref/com/sun/star/drawing/TextFitToSizeType.html
' NONE 			the text size is only defined by the font properties  
' PROPORTIONAL 	if the shape is scaled, the text character size is scaled proportional  
' ALLLINES 		like PROPORTIONAL, but the width of each text row is also scaled proportional.  
' RESIZEATTR 	if the shape is scaled, the font attributes are scaled and hard set on the text

' Standardmäßig wird die Konstante NONE zugewiesen
' Hier eine Zuweisung mit der Konstanten PROPORTIONAL
' passt Text an Rechteck an    
  myAnnotation.annotationShape.TextFitToSize = com.sun.star.drawing.TextFitToSizeType.PROPORTIONAL 

' Listet die Eigenschaften/ Methoden/ Schnittstellen, etc. des Shapes auf  
' xray myAnnotation
' xray myAnnotation.annotationShape
End Sub
Function getAnnotationByCell(aCell As Object) As Object
  Dim result As Object
  Dim annotations As Object
  Dim annotationIndex As Long
  Dim anAnnotation As Object
    Dim isFound As Boolean
  
  annotations = aCell.spreadSheet.annotations
  While ((annotationIndex < annotations.count) and (not isFound))
          anAnnotation = annotations.getByIndex(annotationIndex)
          isFound = ((anAnnotation.position.row = aCell.cellAddress.row) and _
(anAnnotation.position.column = aCell.cellAddress.column))
    If (isFound) Then
      result = anAnnotation
    End If
    annotationIndex = annotationIndex + 1
  Wend
  getAnnotationByCell = result
End Function

Code: Alles auswählen

xray myAnnotation

Code: Alles auswählen

' Beschreibung der möglichen Konstanten, wie sich der Text, bsz. das Kommentarfeld verhält.
' https://www.openoffice.org/api/docs/common/ref/com/sun/star/drawing/TextFitToSizeType.html
' NONE 			the text size is only defined by the font properties  
' PROPORTIONAL 	if the shape is scaled, the text character size is scaled proportional  
' ALLLINES 		like PROPORTIONAL, but the width of each text row is also scaled proportional.  
' RESIZEATTR 	if the shape is scaled, the font attributes are scaled and hard set on the text

' Standardmäßig wird die Konstante NONE zugewiesen
' Hier eine Zuweisung mit der Konstanten PROPORTIONAL
' passt Text an Rechteck an    
  myAnnotation.annotationShape.TextFitToSize = com.sun.star.drawing.TextFitToSizeType.PROPORTIONAL 

Code: Alles auswählen

REM Bibliotheken bei LibreOffice-Start laden
Sub LoadingLibraries

	' Hier in der Basic-IDE -> Objektkatalog
	' LibreOffice Makros & Dialoge -> Tools
'	Globalscope.BasicLibraries.LoadLibrary ( "Tools")
	' load TOOLS library with helper function
	If NOT GlobalScope.BasicLibraries.isLibraryLoaded( "Tools" ) Then
	   GlobalScope.BasicLibraries.LoadLibrary( "Tools" )
	End If
			' https://wiki.openoffice.org/wiki/DE/Makro_Basic_Tutorial
			'http://berma.pagesperso-orange.fr/Files_en/XrayTool60_de.odt
			GlobalScope.BasicLibraries.LoadLibrary("XrayTool")
End Sub