LibreOffice Forum

Code: Alles auswählen

Sub Demo_pListFilenames()
  MsgBox pListFilenames("D:\00_Allgemein","*.*",Chr(10))
End Sub

Function pListFilenames(ByVal strPfd As String, _
               Optional ByVal strMst As String, _
               Optional ByVal strTrn As String, _
               Optional ByVal bolPfd As Boolean) As String

' Gibt die Dateinamen des Verzeichnisses strPfd
' mit bzw. ohne Pfadangabe zurück. 

' PARAMETER:
' strPfd             Der zu durchsuchende Ordner mit vollständiger Pfadangabe
' strMst  [Optional] Suchmuster; Standard ist *.*
' strTrn  [Optional] Trennzeichen zwishen den zurückgegebenen (Pfad- und) Dateinamen; Standard ist das Komma (",")          
' bolPfd  [Optional] Gibt an, ob gefundene Dateinamen MIT oder OHNE Pfadamgabe zurückgegeben werden; Standard ist OHNE


  Dim m As String, c As String, s As String                          
  

' STANDARDWERTE FÜR OPTIONALE PARAMETER
  If IsMissing(strMst) Then strMst = "*.*"                      'Standard-Suchmuster:   Alle Dateien
  If IsMissing(strTrn) Then strTrn = ","                        'Standard-Trennzeichen: Komma (",")
  If IsMissing(bolPfd) Then bolPfd = False                      'Standard-Einstellung:  Dateien OHNE Pfad listen


' WEGWEISER ZUR FEHLER-ROUTINE
  On Error GoTo Err_pListFilenames
  

' MIT SUCHMUSTER ÜBEREINSTIMMENDE DATEINAMEN LISTEN
  If Right(strPfd, 1) <> "\" Then strPfd = strPfd & "\"         'Sicherstellen, dass Pfad mit Backslash ("\") endet
  c = Dir(strPfd & "*.*", 0)                                    'Erste Datei im Ordner suchen
  Do While c <> ""                                              'Schleife solange eine Datei gefunden wurde
    If c Like strMst Then                                       '  Wenn gefundene Datei dem Suchmuster entspricht
      If bolPfd = True Then s = s & strPfd                      '    Ggf. gefundener Datei die Pfadangabe voranstellen
      s = s & c & strTrn                                        '    Gefundene Datei plus Trennzeichen anfügen
    End If                                                      '  Ende Wenn
    c = Dir()                                                   '  Nächste Datei im Ordner suchen
  Loop                                                          'Ende Schleife
  If s <> "" Then s = Left(s, Len(s) - Len(strTrn))             'Ggf. Letztes Trennzeichen entfernen
  pListFilenames = s                                            'Rückgabewert setzen


Exit_pListFilenames:                                          'SM: Ausgang
  Exit Function                                                 'Diese Prozedur verlassen

Err_pListFilenames:                                           'SM: Fehler
  m = "Fehler-Nr.: " & Err & " in Zeile " & Erl & Chr(10)       'Fehlermeldung erstellen
  MsgBox m & Error$: Resume Exit_pListFilenames                 'Meldung ergänzen & zeigen, weiter bei SM: Ausgang

End Function

Code: Alles auswählen

from pathlib import Path
from msgbox import MsgBox

def messagebox( message, deko=None, title="Read_ME" ):
    msg = MsgBox( XSCRIPTCONTEXT.ctx )
    msg.addButton( 'ok' )
    msg.addButton( 'cancel' )
    msg.show( message, deko, title)

    
def main():
    """
    siehe auch https://docs.python.org/3.15/library/pathlib.html#pathlib.Path.glob
    python benutzt normale / slashes auch auf windows als Pfadtrenner
    """
    rootpath = Path.home() / "Downloads" 
    pdfs = '\n'.join(f"{p.name}" for p in rootpath.glob("**/*.pdf")  )
    messagebox(pdfs, title="gugge da die pdfs")

Code: Alles auswählen

sub main()	
	sfa = createUnoService("com.sun.star.ucb.SimpleFileAccess")
	files = sfa.getFolderContents("file:///D:/00_Allgemein/", True)
	dim out(ubound(files))	
	for each file in files
		if right(file, 4) = ".pdf" then
			out(i) = array(file)
			i = i+1
		end if
	next	
	redim preserve out(i-1)	
	thisComponent.Sheets(0).getCellRangeByName("A1:A" & i).DataArray = out     
end sub

Code: Alles auswählen

if lcase(right(file, 4)) = ".pdf" then

Code: Alles auswählen

pdfs = list(filter(lambda file: file.lower().endswith('.pdf'),
                   sfa.getFolderContents("file:///D:/00Allgemein",False)))