Seite 1 von 1
Abfrage auf Dokumentenart
Verfasst: Di 22. Nov 2011, 10:12
von Lordkiri
Hallo zusammen,
gibt es eine Möglichkeit per Makro abzufragen um welche Art von Dokument es sich handel, also writer, calc oder impress, bei thiscomponent bzw. stardesktop.currentcomponent.
Wäre sehr wichtig für mich, da ich eine "globale" Funktion schreiben möchte, die aber kleine Unterschiede aufweist bei eben den unterschiedlichen Dokumenttyp.
Gruß
Lordkiri
Re: Abfrage auf Dokumentenart
Verfasst: Di 22. Nov 2011, 11:53
von gogo
schau mal: OpenOffice.org Macros Explained, (Andrew Pitonyak) so ab etwa Seite 225
dort ist die Basis für folgende 2 Makros:
Code: Alles auswählen
sub TesteDas
print getDocType
end sub
function getDocType(optional oDoc) as String
getDocType = "noch unbekannt"
on Error goto Oops
if isMissing(oDoc) then oDoc = ThisComponent
If oDoc.supportsService("com.sun.star.text.OfficeTextDocument") Then
getDocType = "Writer Dokument"
ElseIf oDoc.supportsService("com.sun.star.sheet.OfficeSpreadsheetDocument") Then
getDocType = "Calc Dokument"
ElseIf oDoc.supportsService("com.sun.star.drawing.OfficeDrawingDocument") Then
getDocType = "Draw Dokument"
ElseIf oDoc.supportsService("com.sun.star.presentation.OfficePresentationDocument") Then
getDocType = "Impress Dokument"
ElseIf oDoc.supportsService("com.sun.star.formula.OfficeFormulaProperties") Then
getDocType = "Formel Dokument"
ElseIf oDoc.supportsService("com.sun.star.sdb.OfficeDatabaseDocument") Then
getDocType = "Datenbank Dokument"
ElseIf oDoc.supportsService("com.sun.star.script.BasicIDE") Then
getDocType = "Basic IDE"
Else
getDocType = "unbekannt"
End if
On error goto 0
exit function
oops:
if Err <> 0 Then getDocType = "unbekannt (nach Fehler)"
On error goto 0
end function
Re: Abfrage auf Dokumentenart
Verfasst: Do 24. Nov 2011, 09:52
von Lordkiri
Danke für die Antwort, mit deiner Hilfe habe ich es hinbekommen.
Man muss nur bei jedem Services das Office weglassen...
Gruß
LordKiri
Re: Abfrage auf Dokumentenart
Verfasst: Do 24. Nov 2011, 12:05
von gogo
ich liebe solche Umstellungen ...