Spezielle Matrixformel aus xls funktioniert nicht in LO.calc

[LORI]

Hallo Gemeinde,
Normalerweise habe ich keine Schwierigkeiten, Formeln (auch Matrixformeln) von xls nach LO zu übernehmen (zumindest dann, wenn ich eine xls(x)-Datei in LO öffne).
Diese xls-Formel jedoch läuft bei mir in LO nicht:
In A1 stehe max. 21-mal die 1, also '111111111111111111111 als Text, zur Dezimalzahl umgewandelt sollte das 2097151 ergeben (tut es in xls auch).
Die Formel heisst:

{=SUMME(TEIL(A1;ZEILE(INDIREKT("1:"&LÄNGE(A1)));1)
*WAHL(21-LÄNGE(A1)+ZEILE(INDIREKT("1:"&LÄNGE(A1)))
;2^20;2^19;2^18;2^17;2^16;2^15;2^14;2^13;2^12;2^11
;2^10;2^9;2^8;2^7;2^6;2^5;2^4;2^3;2^2;2^1;2^0))}

(es geht auch nicht mit 1,11111111111111E+020 als Zahl, also 111111111111111000000 (anders kann ja weder xl noch LO eine 21-stellige Zahl wiedergeben)

Eine äquivalente Formel (für einen kürzeren Binär-String -max. 10xdie 1- heisst:

={SUMMENPRODUKT(TEIL(A1;ZEILE(INDIREKT("1:"&LÄNGE(A1)));1)
*WAHL(10-LÄNGE(A1)+ZEILE(INDIREKT("1:"&LÄNGE(A1)))
;2^9;2^8;2^7;2^6;2^5;2^4;2^3;2^2;2^1;2^0))}

wobei ich auch in xl das als MtxFo eingeben muss (zu meiner Überraschung), so dass ich keinen Vorteil davon habe.
In beiden Fällen erhalte ich #REF! als Fehlermeldung.

Kann mir jemand erklären, woran das liegt, ob ich was falsch mache und wie es ggf ginge?

Ich wollte die Umkehr-Formel zu Basis(2;Zahl) erstellen (die ja bis 2^47 korrekt geht) und das BinInDez aus xl hat mir nicht gereicht (bei 2^9-1 =511 ist Schluss), in LO hab ich diese Formel überhaupt nicht gefunden. Es geht mir aber auch ums Verständnis!
Gruß und danke für Eure Bemühungen,
Lori

[mikele]

Hallo,
ein interessanter Ansatz zur Umwandlung.

1) binindez() heißt auch in LO so
2) Folgende Matrixformel sollte funktionieren

Code: Alles auswählen

{=SUMME(WERT(TEIL(A1;ZEILE(INDIREKT("a1:a"&LÄNGE(A1)));1))*2^(LÄNGE(A1)-ZEILE(INDIREKT("a1:a"&LÄNGE(A1)))))}

3) Die "Excelformel" scheitert, weil LO Adressen wie 1:1 (für die gesamte 1. Zeile) nicht kennt.

[karolus]

Hallo

Nimm

Code: Alles auswählen

=DEZIMAL(A1;2)

Karolus

[LORI]

Seid Ihr schnell! danke! Auf dieses Zeile(1:1)/Spalte(A:A) hab ich andere schon so oft drauf hingewiesen, und dann erkenn ich den Fehler selber nicht! (grummel )
ach ja, und dann auch noch der viel kürzere Ansatz Deiner Formel... (und sie funktioniert auch! und auch die andere, Dezimal(A1;2))
Also es bleibt dabei: Eure Formeln tun.

Was mich aber verwirrt: ich hab in meiner 1.Formel jetzt das "1:"& zweimal geändert zu "A1:A"& und in xls tut es jetzt weiterhin, aber in LO immer noch nicht! (Es geht mir jetzt nur noch ums Verständnis!)
Habs hingekriegt: das Wert(ums 1.Argument) muss in LO noch rein!