Zwischenergebnis weiterverwenden

[UlfZibis]

Hallo,
wie kann man das Ergebnis einer Teilberechnung in einer dieses mehrfach benutzenden weiteren Berechnung wiederverwenden, ohne dass man die Formel der Teilberechnung immer wieder kopieren muss?

Mein Beispiel:
Ich habe Telefonnummern in folgendem Format in der Rohdaten-Tabelle:
"888"
"077888"
"002277888"
"+4977888"
Als Resultat hätte ich dann gerne in der Ergebnis-Tabelle:
888
+4977888
+2277888
+4977888
Gänsefüßchen entfernen:
Schritt_1=WECHSELN($Rohdaten.$E1234;"""";"")
"00" am Anfang durch "+" ersetzen:
Schritt_2=ERSETZEN(Schritt_1;1;2;WECHSELN(TEIL(Schritt_1;1;2);"00";"+";1))
"0" am Anfang durch "+49" ersetzen:
Ergebnis=ERSETZEN(Schritt_2;1;1;WECHSELN(TEIL(Schritt_2;1;1);"0";"+49";1))
Wenn man einen der Schritte eleganter machen kann, freue ich mich ebenfalls auf Vorschlage!

Wenn ich das ineinander verschachtele bekomme ich folgendes Ungetüm:
Ergebnis=ERSETZEN(ERSETZEN(WECHSELN($Rohdaten.$E1234;"""";"");1;2;WECHSELN(TEIL(WECHSELN($Rohdaten.$E1234;"""";"");1;2);"00";"+";1));1;1;WECHSELN(TEIL(ERSETZEN(WECHSELN($Rohdaten.$E1234;"""";"");1;2;WECHSELN(TEIL(WECHSELN($Rohdaten.$E1234;"""";"");1;2);"00";"+";1));1;1);"0";"+49";1))

Ich kann mir nicht vorstellen, dass das die einzig mögliche Lösung in Calc sein kann.
Es gibt da ja die Funktion AKTUELL(), doch verstehe ich nicht, wie ich die syntaktisch richtig hier einbauen könnte.

[mikele]

Hallo,
formeltechnisch wird es nicht viel einfacher werden. Die Frage ist, ob du das einmalig (mit einer Tabelle) machen willst oder ob du das häufiger brauchst. Für die einmalige Bearbeitung wirst du mit Suchen&Ersetzen schneller sein.

[mikele]

Hallo,
eine alternative Formel (in A1 sei der Rohtext):

Code: Alles auswählen

=WENN(TEIL(A1;2;2)="00";"+";WENN(TEIL(A1;2;1)="0";"+49"&TEIL(A1;3;1);TEIL(A1;2;2)))&TEIL(A1;4;LÄNGE(A1)-4)

[UlfZibis]

Hallo,
eine alternative Formel (in A1 sei der Rohtext):

Code: Alles auswählen

=WENN(TEIL(A1;2;2)="00";"+";WENN(TEIL(A1;2;1)="0";"+49"&TEIL(A1;3;1);TEIL(A1;2;2)))&TEIL(A1;4;LÄNGE(A1)-4)

Danke, auch ein interessanter Ansatz, der mit A1 zusätzlich schick aussieht. Ich müsste darin A1 allerdings 6 mal statt 4 mal durch $Rohdaten.$E1234 ersetzen.
Weiterhin sind da leider 2 Fehler drin:
1. Aus "002277888" wird +49 wird +49277888
2. Aus "077888" wird +49 wird +49888

EDIT: Oh sorry, hab' falschrum gedacht, müsste doch funktionieren.

[Lupo]

=GLÄTTEN(WECHSELN(WECHSELN(" "&WECHSELN($Rohdaten.$E1234;"""";"");" 00";" +");" 0";"+49"))

[UlfZibis]

=GLÄTTEN(WECHSELN(WECHSELN(" "&WECHSELN($Rohdaten.$E1234;"""";"");" 00";" +");" 0";"+49"))

Wow, das ist ja ein geiler Trick.
Und falls in den Rohdaten doch mal das ein oder andere Leerzeichen drin sein sollte, kann man ja auch mehrere Leerzeichen voranstellen.