LibreOffice-Forum

Hallo,
gibt es die möglichkeit Uhrzeiten ohne Doppelpunkt einzugeben?

Wie z.B bei Excel

https://www.youtube.com/watch?v=HXqsuWxT9Fs

Gruß Mondblatt24

Hallo,
Zellformat so definieren:

Code: Alles auswählen

HH.MM.SS

Ciao

miesepeter hat geschrieben:Zellformat so definieren:
Code: Alles auswählen
HH.MM.SS
Ciao

Das war ein Schnellschuss, der nicht zielführend sein kann.

Aufgabe ist doch, die zwei Kommata durch einen Doppelpunkt zu ersetzen.

In Calc funktioniert das ähnlich wie bei Excel. Bei der Eingabe muss nach den Stunden zunächst aber ein Leerzeichen zwischengeschaltet werden. Nach Eingabe der zwei Kommata muss ein weiteres Leerzeichen geschaltet werden werden. Dann erfolgt erst die automatische Ersetzung, durch den Doppelpunkt. Nach Verlassen der Zelle wird die Zeitangabe richtig erkannt und die Leerzeichen sind verschwunden.

Warum die Leerzeichen? Weil das zu ersetzende Zeichen/Wort frei stehen muss.

Hallo,

Danke genau das habe ich gesucht

Gruß Mondblatt24

Hallo

LO akzeptiert inzwischen (in der Autoersetzung) auch in begrenzten Umfang reguläre Ausdrücke, damit kommst du dann ohne Leerzeichen vor|hinter der Eingabe aus:

.*,,.* ……… :

Hier eine für mich gute Lösung.

Downloadlink of example file: https://public.andreasburg.de/ooo/ooo-time-input.ods

Apache OpenOffice 4.1.5

Die Eingabefelder für Uhrzeiten so formatieren

Code: Alles auswählen

#0:0#

Dort kann man die Uhrzeiten jetzt so eintragen

Code: Alles auswählen

Uhrzeit - Eingabe - Anzeige
12:00   - 1200    - 12:00
07:30   -  730    -  7:30
00:15   -   15    -  0:15
00:05   -    5    -  0:05

Will man diese Uhrzeiten jetzt in Formeln für Berechnungen heranziehen, muss man sie vorher in eine Zeit umwandeln. Man kann z.B. neben der Spalte in welche man die Zeit einträgt eine Spalte einrichten, welche dann den richtigen Zeitwert enthält.

Für die Umrechnung benutzt man die Formel

Code: Alles auswählen

ZEIT(Stunde; Minute; Sekunde)

Die Stunden holt man so (Feld A2)

Code: Alles auswählen

=LINKS(A2;LÄNGE(A2)-2)

Die Minuten holt man so (Feld A2)

Code: Alles auswählen

=RECHTS(A2;2)

(Die Sekunden in der Formel setzt man auf '0'.)

Jetzt kann man die Stunden, Minuten und Sekunden in die Funktion ZEIT() eintragen

Code: Alles auswählen

=ZEIT(LINKS(A2;LÄNGE(A2)-2);RECHTS(A2;2);0)

Da der zweite Parameter für ZEIT() (LÄNGE(A2)-2) nicht kleiner werden darf als 0 muss man noch prüfen, ob der eingegebene Zeitwert mindestens 2 Zeichen lang ist, wenn nicht dann setzt man ihn auf '0'. Hier die neue Berechnung für die Stunden

Code: Alles auswählen

=WENN(LÄNGE(A2)>1;LINKS(A2;LÄNGE(A2)-2);0)

Die komplette Formel für das Feld, welches den berechneten Zeitwert enhält (B2) sieht nun so aus.

Code: Alles auswählen

=ZEIT(WENN(LÄNGE(A2)>1;LINKS(A2;LÄNGE(A2)-2);0);RECHTS(A2;2);0)

Das Feld B2 kann man dann noch zur schönen Ansicht formatieren wie man möchte, z.B. mit

Code: Alles auswählen

H:MM

Damit B2 nur einen Wert anzeigt, wenn A2 auch einen Wert hat, kann man z.B. die Funktion ANZAHL() benutzen. Dies geht auch mit anderen Prüfungen, aber wenn man direkt mehrere Felder prüfen möchte ist ANZAHL() sehr einfach.

Code: Alles auswählen

=WENN(ANZAHL(A2)=1;ZEIT(WENN(LÄNGE(A2)>1;LINKS(A2;LÄNGE(A2)-2);0);RECHTS(A2;2);0);"")

LibreOffice-Forum

[GELÖST]Uhrzeit eingeben ohne Doppelpunkt

[GELÖST]Uhrzeit eingeben ohne Doppelpunkt

Re: Uhrzeit eingeben ohne Doppelpunkt

Re: Uhrzeit eingeben ohne Doppelpunkt

Re: Uhrzeit eingeben ohne Doppelpunkt

Re: Uhrzeit eingeben ohne Doppelpunkt

Lösung für einfache Zeiteingabe (Stunden und Minuten)