Seite 1 von 1
mehrere Wörter in Spalte suchen
Verfasst: Do 21. Jun 2018, 18:19
von sk0815
Hallo, ich habe eine spalte erstellt in dem ich einen Text eingeben kann.
Wenn darin das Wort "Wartung" oder "Störung" eingegeben wird dann soll in eine bestimmte Zelle etwas eingetragen werden.
Das funktioniert auch mit folgender Formel:
=WENN(ISTFEHLER(SUCHEN("wartung";$G$3));"";$BK$5) & WENN(ISTFEHLER(SUCHEN("störung";$G$3));"";$BK$5)
wenn ich aber nach noch mehr Wörtern suchen möchte wird die Formel ewig lang....
Kann ich nicht auch bei suchen( dann beide oder auch mehrere Wörter eingeben nach denen gesucht wird?
Re: mehrere Wörter in Spalte suchen
Verfasst: Do 21. Jun 2018, 19:22
von HeritzP
Hallo,
mit Verkettungszeichen.
Code: Alles auswählen
=WENN(ISTFEHLER(SUCHEN("Wartung|störung";$G$3;1));12;$BK$5)
oder mit VERBINDEN(). Zellbereich I3:I9 ist eine Liste von Suchwörtern.
Code: Alles auswählen
=WENN(ISTFEHLER(SUCHEN(VERBINDEN("|";1;I3:I9);$G$3;1));12;$BK$5)
Gruß HeritzP
Re: mehrere Wörter in Spalte suchen
Verfasst: Fr 22. Jun 2018, 07:42
von Lupo
Ich habe das anders verstanden:
=WENN(SUMMENPRODUKT(--ISTZAHL(SUCHEN({"Wartung";"Störung"};$G$3)));$BK$5;"")
oder allgemein mit Wortliste in Bereich:
=WENN(SUMMENPRODUKT(--ISTZAHL(SUCHEN($I$3:$I$9;$G$3)));$BK$5;"")
TE will m.E. BK5 zeigen, falls eines der Wörter gefunden wird.
Hallo HeritzP, was meinst Du denn mit "Wartung|Störung"? Das steht in SUCHEN() an der Stelle des Suchstrings, nicht an der des Strings, in welchem gesucht wird.
Re: mehrere Wörter in Spalte suchen
Verfasst: Fr 22. Jun 2018, 11:02
von sk0815
Das hat leider nicht funktioniert;
=WENN(ISTFEHLER(SUCHEN("Wartung|störung";$G$3;1));12;$BK$5)
Diese Formel verstehe ich zwar nicht ganz, aber sie funktioniert :
=WENN(SUMMENPRODUKT(--ISTZAHL(SUCHEN({"Wartung";"Störung"};$G$3)));$BK$5;"")
Vielen Dank!
Re: mehrere Wörter in Spalte suchen
Verfasst: Fr 22. Jun 2018, 13:07
von HeritzP
Hallo,
mal wieder vergessen zu erwähnen.
Unter Extras -> Optionen -> LibreOffice Calc -> Berechnen -> reguläre Ausdrücke in Formeln ermöglichen.
Das Verkettungszeichen "|" ist ein regulärer Ausdruck. Es wird der Suchbegriff davor und dahinter gesucht.
TE will m.E. BK5 zeigen, falls eines der Wörter gefunden wird.
Ich habe mich nach seiner eigenen Formel orientiert.
Gruß HeritzP
Re: mehrere Wörter in Spalte suchen
Verfasst: Fr 22. Jun 2018, 14:57
von sk0815
=WENN(SUMMENPRODUKT(--ISTZAHL(SUCHEN({"Wartung";"Störung"};$G$3)));$BK$5;"")
Wie kann ich die Formel erweitern, das er das nur macht wenn in dem Feld I7 etwas drin steht?
Re: mehrere Wörter in Spalte suchen
Verfasst: Sa 23. Jun 2018, 05:52
von Lupo
HeritzP hat geschrieben: ↑Fr 22. Jun 2018, 13:07
Unter Extras -> Optionen -> LibreOffice Calc -> Berechnen -> reguläre Ausdrücke in Formeln ermöglichen.
Das Verkettungszeichen "|" ist ein regulärer Ausdruck. Es wird der Suchbegriff davor und dahinter gesucht.
Als altem Excelaner ist mir diese (zugegeben schicke) Syntax fremd, da man dort RegEx nur in VBA dazuschalten kann
Oder: So, wie ich (gelegentlich) versuche, in Excelforen eine LO-kompatible Lösung anzubieten, versuche ich es hier umgekehrt auch.
HeritzP hat geschrieben: ↑Fr 22. Jun 2018, 13:07
Ich habe mich an seiner eigenen Formel orientiert.
Seine Formel war (technisch, nicht unbedingt inhaltlich) unsinnig, da damit der Ausgang
= BK5 & BK5 ermöglicht ist.
sk0815 hat geschrieben: ↑Fr 22. Jun 2018, 14:57
Wie kann ich die Formel erweitern, das er das nur macht wenn in dem Feld I7 etwas drin steht?
=WENN((I7<>"")*SUMMENPRODUKT(--ISTZAHL(SUCHEN({"Wartung";"Störung"};$G$3)));$BK$5;"")
Re: mehrere Wörter in Spalte suchen
Verfasst: Mo 2. Jul 2018, 10:09
von sk0815
Klasse es funktioniert!
=WENN((I7<>"")*SUMMENPRODUKT(--ISTZAHL(SUCHEN({"Wartung";"Störung"};$G$3)));$BK$5;"") & WENN(SUMMENPRODUKT(--ISTZAHL(SUCHEN({"bau";"pkw"};$G$3)));$BK$7;"")
wenn ich nun ein Wort hinzufügen möchte nachdem er sucht, müßte ich es so eintragen oder? ( UNFALL ziemlich am Ende... )
=WENN((I7<>"")*SUMMENPRODUKT(--ISTZAHL(SUCHEN({"Wartung";"Störung"};$G$3)));$BK$5;"") & WENN(SUMMENPRODUKT(--ISTZAHL(SUCHEN({"bau";"pkw";"UNFALL"};$G$3)));$BK$7;"")