BITTE helfen Sie uns HEUTE mit einer SPENDE
Helfen Sie das LibreOffice Forum zu erhalten!

❤️ DANKE >><< DANKE ❤️

> KEINE WERBUNG FÜR REGISTRIERTE BENUTZER!<
Ihre Spende wird für die Deckung der laufenden Kosten sowie den Erhalt und Ausbau 🌱 des LibreOffice Forums verwendet.
🤗 Als Dankeschön werden Sie im Forum als LO-SUPPORTER gekennzeichnet. 🤗

[gelöst] Summe der letzten drei Werte

CALC ist die Tabellenkalkulation, die Sie immer wollten.
Antworten
Criss
Beiträge: 18
Registriert: Di 30. Jan 2018, 16:33

[gelöst] Summe der letzten drei Werte

Beitrag von Criss » Sa 8. Dez 2018, 17:04

Hallo Freunde,

ich bitte um eure Hilfe.
Ich habe eine Tabelle wo in Spalte H um die 20 verschiedene Texte und in Spalte J verschiedene Werte. (Siehe Beispiel.ods)

Mein Problem:
ich möchte in einer Zelle (z.B.Axx) die letzten 3 Werte der Spalte J addieren wenn in Spalte H ein bestimmter Text ist.

Beispiel:

wenn in Spalte H „Ar“ steht dann sollen die letzten 3 Werte von Spalte J (von unten nach oben)
addiert werden, aber NUR die letzte 3 Zeilen addieren wo in Spalte H „Ar“ steht. (siehe Beispiel Filter.ods)
Konkret muss so aussehen:
A68=3 (J53+J30+J17)
A89=4 (J68+J53+J30)

Die Tabelle wird wöchentlich „gefüttert“ und „wächst“ bis ca. 600 Zeilen.

Ich hoffe ich habe es verständlich erklärt, und Ihr könnt mir weiter helfen.
Vielen Dank im Voraus.

Gruß Criss
Dateianhänge
Beispiel Filter.ods
(12.67 KiB) 185-mal heruntergeladen
Beispiel.ods
(20.86 KiB) 183-mal heruntergeladen
Zuletzt geändert von Criss am Do 13. Dez 2018, 17:47, insgesamt 1-mal geändert.

Lupo
Beiträge: 279
Registriert: Do 11. Okt 2012, 14:22

Re: Summe der letzten drei Werte

Beitrag von Lupo » Sa 8. Dez 2018, 18:18

Dateien nicht geöffnet:

{=SUMME(WENN(KGRÖSSTE((A$1:A$99="Ar")*ZEILE(A$1:A$99);{1.2.3})=ZEILE(A$1:A$99);B$1:B$99))} mit Nr. 5
MfG Lupo - xxcl.de Win10ProLO6062

HeritzP
Beiträge: 899
Registriert: Mo 9. Dez 2013, 19:08

Re: Summe der letzten drei Werte

Beitrag von HeritzP » So 9. Dez 2018, 11:00

Hallo,


im Formeleditor als Matrixformel markieren, oder mit STRG, SHIFT und ENTER abschliessen.

Code: Alles auswählen

=SUMME(INDEX(J2:J600;KGRÖSSTE(WENN(H2:H600="Ar";ZEILE(A2:A600);"");ZEILE(A1:A3))-1;1))
oder

Code: Alles auswählen

=SUMME(INDEX(J2:J600;KGRÖSSTE(WENN((H2:H600="Ar")*(ISTZAHL(J2:J600));ZEILE(A2:A600);"");ZEILE(A1:A3))-1;1))
Gruß HeritzP
HeritzP

alles nur geklaut

mikele
Beiträge: 1642
Registriert: Mo 1. Aug 2011, 20:51

Re: Summe der letzten drei Werte

Beitrag von mikele » So 9. Dez 2018, 13:57

Hallo,
wenn ich dich richtig verstanden habe, willst du z. B. in Zeile 60 die letzten drei Werte vor der Zeile 60 finden und entsprechend addieren.
Ab Zeile 6 sollte folgende Formel funktionieren:

Code: Alles auswählen

=SUMME(INDEX(J$1:J5;MAX(KGRÖSSTE((H$3:H5=H6)*ZEILE(H$3:H5);{1.2.3});1)))
Die kannst du bei gedrückter Strg-Taste nach unten ziehen.
Gruß,
mikele

Criss
Beiträge: 18
Registriert: Di 30. Jan 2018, 16:33

Re: Summe der letzten drei Werte

Beitrag von Criss » Mo 10. Dez 2018, 18:09

Hallo,
vielen Dank für eure Antworten, aber keine hilft mir weiter.

@Lupo
ich habe versucht deine Formel an meine Tabelle anzupassen, aber weiß ich nicht was ich
mit der Spalte B anfangen soll. Wenn du nächstes mal mehr Zeit hast, öffne bitte die Dateien,
vielleicht verstehst du besser was ich möchte. Danke

@HeritzP
danke, aber deine Formeln bringen nicht das gewünschte Ergebnis

@mikele
danke dir auch. Du hast richtig verstanden was ich möchte. Die Datei „Beispiel Filter.ods“ habe
ich hochgeladen um die Ergebnisse zu verdeutlichen. Die Formel brauche ich für eine Tabelle
ohne Filter.
Ich habe deine Formel kopiert und eingefügt und das Ergebnis ist #WERT.

Vielleicht habe ich mein Problem
nicht richtig erklärt, deswegen versuche ich nochmal.

Die Formel was ich suche, soll eigentlich wie ein Filter arbeiten, und zwar soll in erster Linie die Zeilen finden wo in Spalte H ein bestimmter Text ist, z.B. „Ar“, dann soll die letzten 3 dazugehörige Werte was in der Spalte J sind, addieren.
Dazugehörige meine ich, wenn in Zeile 53, H53=“Ar“ dann J53 gehört dazu.
In meinem Beispiel gibt es in Zeilen 17, 30, 53, 68, 89, 107 und 122 in Spalte H ein „Ar“. Die Formel was ich suche, soll mir das folgende Ergebnis ausrechnen:
A122= die Zeilen wo in H „Ar“ steht suchen und die letzten 3 Werte von Spalte J, in dem Fall J107, J89, J68 addieren, und wenn die Formel richtig funktioniert, das Ergebnis ist 6. (siehe Beispiel Filter.ods)
A107 muss auch 6 sein (J89+J68+J53)
A89 muss 4 stehen (J68+J53+J30)
A68 muss 3 stehen (J53+J30+J17)

Die Formel möchte ich für die andere Texte, was in Spalte H sind, verketten. Wenn es geht. ;)

Ich hoffe, ich habe nicht zu viel verlangt.

Vielen Dank im Voraus

Gruß Criss

Lupo
Beiträge: 279
Registriert: Do 11. Okt 2012, 14:22

Re: Summe der letzten drei Werte

Beitrag von Lupo » Di 11. Dez 2018, 11:23

Ich nutze doch nur zwei Spalten:

A:A ist die maßgebende Beschriftung
B:B sind die Werte, die gerechnet werden

Dafür öffne ich keine Datei. Und da dies so einfach ist, muss das auch verstanden werden.

PS: Ob ZEILE mit A oder B geschrieben wird, ist übrigens egal.

Wer lange vorher erläutert UND zusätzlich noch eine Datei beipackt, gibt dem Antworter halt eine Entscheidung, eines der beiden auch eben NICHT zu beachten.
MfG Lupo - xxcl.de Win10ProLO6062

mikele
Beiträge: 1642
Registriert: Mo 1. Aug 2011, 20:51

Re: Summe der letzten drei Werte

Beitrag von mikele » Di 11. Dez 2018, 18:34

Hallo Criss,
meine Formel funktioniert leider nicht (aus anderen Gründen).
Lupo's Formel auf deine Situation angepasst:

Code: Alles auswählen

=SUMME(WENN(KGRÖSSTE((H$3:H5=H6)*ZEILE(H$3:H5);{1.2.3})=ZEILE(H$3:H5);J$3:J5))
Als Matrixformel mit Shift+Strg+Enter abzuschließen und beim Ziehen nach unten die Strg-Taste gedrückt halten.
Eine Variante als Nichtmatrixformel (vorausgesetzt, die zu addierenden Werte sind positiv und in der Summe nie größer als 999):

Code: Alles auswählen

=REST(SUMMENPRODUKT(KGRÖSSTE((H$3:H5=H6)*(ZEILE(H$3:H5)*1000+J$3:J5);{1.2.3}));1000)
oder (wieder allgemeingültiger)

Code: Alles auswählen

=SUMMENPRODUKT((KGRÖSSTE((H$3:H5=H6)*(ZEILE(H$3:H5));{1.2.3})=(ZEILE(H$3:H5)))*(J$3:J5))
Anmerkung: Intern laufen alle drei Formeln über Matrizen. Dabei ist erstaunlich, welche Form diese Matrizen annehmen, sodass bestimmte Formelkonstruktionen eben nicht funktionieren.

Code: Alles auswählen

(KGRÖSSTE((H$3:H5=H6)*(ZEILE(H$3:H5));{1.2.3})=(ZEILE(H$3:H5))
liefert z B. eine 3x3 Matrix obwohl ich eine 3x1 Matrix erwartet hätte. Bei höheren Zeilennummern wird es eine 3xn Matrix ...
Gruß,
mikele

Criss
Beiträge: 18
Registriert: Di 30. Jan 2018, 16:33

Re: [gelöst]Summe der letzten drei Werte

Beitrag von Criss » Mi 12. Dez 2018, 16:54

Hallo Mikele,

vielen, vielen Dank, deine beide Formel funktionieren einwandfrei, sie machen genau das was ich wollte.
Danke auch für die "übersetzte" Version von Lupo, es funktioniert auch.
Und noch ein Danke für deine geduldige und "Idioten sichere" Art zu erklären wie die Formel "ticken". ;)

Gruß Criss

An alle, die das LibreOffice-Forum nutzen:


Bitte beteiligen Sie sich mit 7 Euro pro Monat und helfen uns bei unserem Budget für das Jahr 2024.
Einfach per Kreditkarte oder PayPal.
Als Dankeschön werden Sie im Forum als LO-SUPPORTER gekennzeichnet.

❤️ Vielen lieben Dank für Ihre Unterstützung ❤️

Antworten