Seite 1 von 1
[gelöst] Nettoarbeitstage in Kombination mit Wochentag und Arbeitszeit für jeden Wochentag
Verfasst: Sa 18. Mär 2023, 00:22
von Rafter
Hallo,
ich würde gerne die Funktion "Nettoarbeitstage" mit "Wochentag" verknüpfen und dabei in der Gleichung jedem Wochentag eine Arbeitszeit zuweisen. Damit ich ausgehend vom Startdatum und Enddatum, die Summe der Arbeitsstunden erhalte.
Gegeben sind nur Anfangsdatum und Enddatum:
z.B.
A1 = 01.01.2023
A2 = 01.02.2023
Nehmen wir einmal an, die tägliche Arbeitszeit liegt bei:
Mo. = 6 Stunden,
Di. = 5 Stunden,
Mi. = 4 Stunden,
Do. = 8 Stunden,
Fr. = 3 Stunden,
Sa. = 0 Stunden,
So. = 0 Stunden.
Lässt sich das realisieren ohne irgendwelche Hilfszeilen zu verwenden? Also einzig aus den beiden Werten in A1 und A2 heraus?
Wäre wohlmöglich eine lange Formel, da ausgehend von A1 und nachfolgend, jedem Wochentag die Arbeitszeit in der Formel definiert sein müsste. Aber sicher machbar.
Erbitte Lösungsvorschläge.
Viele Grüße
Raphael
Re: Nettoarbeitstage in Kombination mit Wochentag und Arbeitszeit für jeden Wochentag
Verfasst: Sa 18. Mär 2023, 07:05
von echo
Hallo
=NETTOARBEITSTAGE.INTL(A1;A2;"0111111")*6
Arbeitsstunden nur Montag
0111111 = Jede Ziffer steht für einen Wochentag Montag - Sonntag
0 = Zählen ; 1 = nicht zählen
Zusätzlich könntest du auch noch eine Matrix angeben in der mögliche Feiertage stehen, siehe (Fx) Formeleditor
Gruß Holger
Nachtrag: Beispiel, in D1 wird der Wochentag gewählt
Re: Nettoarbeitstage in Kombination mit Wochentag und Arbeitszeit für jeden Wochentag
Verfasst: Sa 18. Mär 2023, 07:38
von RPP63
Moin!
Ich nehme an, dass in Calc eine Monsterformel vonnöten ist.
Deshalb off topic:
In meinem aktuellen Excel kann man das mit einer sehr übersichtlichen Formel lösen.
Code: Alles auswählen
=SUMME(INDEX({6.5.4.8.3.0.0};VERGLEICH(WOCHENTAG(SEQUENZ(A2-A1+1;;A1);2);SEQUENZ(7))))
Ergebnis ist: 119 Stunden.
Gruß Ralf
Re: Nettoarbeitstage in Kombination mit Wochentag und Arbeitszeit für jeden Wochentag
Verfasst: Sa 18. Mär 2023, 07:47
von karolus
Hallo
mit
nur einer Hilfszelle A3 mit der Formel:
Code: Alles auswählen
=SUMME(
(WOCHENTAG(ZEILE(INDIREKT(A3));2)=1)/4;
(WOCHENTAG(ZEILE(INDIREKT(A3));2)=2)*5/24;
(WOCHENTAG(ZEILE(INDIREKT(A3));2)=3)/6;
(WOCHENTAG(ZEILE(INDIREKT(A3));2)=4)/3;
(WOCHENTAG(ZEILE(INDIREKT(A3));2)=5)/8)
Re: Nettoarbeitstage in Kombination mit Wochentag und Arbeitszeit für jeden Wochentag
Verfasst: Sa 18. Mär 2023, 09:48
von karolus
Heureka!!
Achtung Formeln korrigiert 19.3.23 12:00Uhr
Code: Alles auswählen
=SUMMENPRODUKT(WAHL(WOCHENTAG(ZEILE(INDIREKT(WOCHENTAG(A1)&":"&A2-A1+WOCHENTAG(A1)));2);6;5;4;8;3;0;0))
gibt direkt die Anzahl der Stunden aus
ODER
Code: Alles auswählen
=SUMMENPRODUKT(WAHL(WOCHENTAG(ZEILE(INDIREKT(WOCHENTAG(A1)&":"&A2-A1+WOCHENTAG(A1)));2);1/4;5/24;1/6;1/3;1/8;0;0))
gibt die Summe in Tages-Einheiten aus, und muss daher formatiert werden im Zahlenfomatcode
[HH]:MM:SS
Re: Nettoarbeitstage in Kombination mit Wochentag und Arbeitszeit für jeden Wochentag
Verfasst: Mo 20. Mär 2023, 00:05
von Rafter
Danke für die zahlreichen Antworten.
Karolus' und Ralfs Vorschläge sehen gut aus. So in etwa hatte ich mir das vorgestellt.
Allerdings geben beide Formeln falsche Ergebnisse aus. Oder übersehe ich etwas?
Beide Ansätze liefern aber die gleichen Ergebnisse. Ralfs Ansatz funzt bei mir aber nur in excel.
Librecalc hat offenbar Probleme mit der Sequenz Funktion.
Die Berechnung muss auch mit Teil-Stunden funktionieren, daher geht Holgers Vorschlag nicht.
Im Anhang sind eure beiden Vorschläge eingefügt.
Daneben die richtigen Werte, die aus der Tabelle Arbeitszeit mit dem darunter liegenden Kalender, die Arbeitsstunden pro Tag angibt und die Summe derer pro Monat ausgibt.
Könnt ihr das bitte nochmal überprüfen bzw. mich korrigieren wenn ich hier etwas nicht verstanden habe.
Viele Grüße
Raphael
Re: Nettoarbeitstage in Kombination mit Wochentag und Arbeitszeit für jeden Wochentag
Verfasst: Mo 20. Mär 2023, 07:31
von karolus
Hallo
Ralfs Ansatz funzt bei mir aber nur in excel.
Librecalc hat offenbar Probleme mit der Sequenz Funktion.
Ralf hat klar geschrieben, daß die Formel
nur in Excel funktioniert.
Oder übersehe ich etwas?
ja du übersiehst das beide Formeln
einschliesslich »End_Datum« berechnen … deine Korrekturen berechnen aber
ausschliesslich »End_Datum«
Falls du daß
ausschliesslich möchtest, musst du in meiner Formel bsplw.
E3-E2 gegen
E3-E2-1 tauschen!
die Funktion NETTOARBEITSTAGE rechnet übrigens auch
einschliesslich End_Datum
Schau dir BITTE auch die geänderte und ergänzte Datei im Anhang an, da wird die komplette Berechnung der Stunden pro Monat über eine Pivottabelle realisiert, ohne irgendwo fehleranfällige Raketenwissenschaftliche Formeln zu benötigen.
Re: Nettoarbeitstage in Kombination mit Wochentag und Arbeitszeit für jeden Wochentag
Verfasst: Mo 20. Mär 2023, 11:27
von Rafter
Hallo,
so einfach. Wunderbar!
Sorry, hätte angeben müssen, dass es mir nur um die Arbeitsstunden je Monat geht und genauer lesen sollen.
Vielen Dank für die schnelle Unterstützung!
Re: Nettoarbeitstage in Kombination mit Wochentag und Arbeitszeit für jeden Wochentag
Verfasst: Mo 20. Mär 2023, 13:25
von Mondblatt24
Hallo,
Rafter hat geschrieben: ↑Mo 20. Mär 2023, 11:27
Arbeitsstunden je Monat
Gibt es bei euch gar keine Feiertage?
Gruß
Peter
Re: [gelöst] Nettoarbeitstage in Kombination mit Wochentag und Arbeitszeit für jeden Wochentag
Verfasst: Mo 20. Mär 2023, 19:57
von Rafter
Doch, aber in diesem Fall, unbedeutend, da bezahlt.