Zellinhalt teilen

[Aehzebaer]

Hallo,

ich habe Zellinhalte wo ich eine Artikelnummer bestehend aus Buchstaben und Zahlen (keine Leerzeichen!) trennen muss:

abc123
derfg789544
ztrf01645

Die Trennung erfolgt mit der ersten Zahl. Die Zahl soll als Text (also mit führender Null) dargestellt werden.

Nach der Trennung sollen Buchstaben und Zahl in zwei verschiedenen Zellen stehen:
abc 123
derfg 789544
ztrf 01645

Wie kann ich das hinbekommen?

[bst]

Hi,

mal ein Versuch. Trennt die Werte aus Spalte A und schreibt das nach B und C.

HTH, Bernd
--

Code: Alles auswählen

REM  *****  BASIC  *****

Sub Main
	dim oSheet as Object
	dim i as Long, iMax as Long
	dim ar
		
	oSheet = ThisComponent.currentController.ActiveSheet
	iMax = getLastRowInColumn(oSheet, 0) ' 0 = A, 1 = B, 2 = C
	for i = 0 to iMax
		ar = mySplit(oSheet.getCellByPosition(0, i).String)
		oSheet.getCellByPosition(1, i).string = ar(0)
		oSheet.getCellByPosition(2, i).string = ar(1)
	next	 
End Sub

Function getLastRowInColumn(oSheet as Object, iColumn as integer) as Long
	dim oUsedCells as Object
	
	oUsedCells = oSheet.Columns(iColumn).queryContentCells(23)
	getLastRowInColumn = oUsedCells.RangeAddresses(oUsedCells.Count-1).endRow
End Function

Function mySplit(strVal as string) as Variant
	dim ar(0 to 1)
   	dim i as Long
   
   	for i = 1 to len(strVal)
		if mid(strVal, i, 1) Like "#" then exit for	   	
   	Next
   	ar(0) = left(strVal, i-1)
   	ar(1) = mid(strVal, i)
   	
   	mySplit = ar
End Function   

[karolus]

Hallo
zuerst:

• →Bearbeiten→Suchen und ersetzen
  suche nach
  \d+$
  ersetze durch
  |$0
  mit der Option: regulärer Ausdruck
  →→ersetze alle

Danach markiere die ganze Spalte und gehe zu:

• →Daten→Text in Spalten
  wähle als Trennzeichen [x]sonstige |
  und stelle in der Vorschau die rechte Spalte um, von 'Standard' auf 'Text'

Karolus

[Aehzebaer]

@bst und karolus:

funktioniert beides. Problem gelöst.

Vielen Dank für Eure Arbeit!