Speichern mit Name aus Textfeld

[Atwist]

Hallo zusammen,

Versuche Grade ein paar Dokumenten zu vereinfachen mittels Textfeld und Makro aber krieg es nicht hin was ich will.
Will bei druck auf die schalt-flache "speichern" das es mittels ein Makro das Dokument als PDF mit die Name aus einen Textfeld gespeichert wert.

Code: Alles auswählen

    Sub Savetopdf
    On error goto EH
    oDoc = ThisComponent
    oTFS = oDoc.getTextFields
    enum = oTFS.createEnumeration
    While enum.hasMoreElements
    oTF = enum.nextElement
    Select Case oTF.Content
    Case "Anrede" : A = oTF.Anchor.String
    Case "Datum" : D = oTF.Anchor.String
    Case "Referentie" : R = oTF.Anchor.String
    End Select
    Wend
    U = "-"
    filename = A & U & D & U & R & U & ".pdf"
    url = ConvertToURL("file:///media/documenten/PDF/" & filename)'Insert Your Desired Directory Path.
    oDoc.StoreAsURL(url,Array())
    oDoc.Modified = false 'avoid Save being called if doc closed without further edits.
    End 'end normal execution.
    EH: 'error handler.
    MsgBox "You may have illegal file name character." & Chr(13)_
    & Chr(13) & filename,,"AN ERROR OCCURRED"
    End Sub

Kann jemand mir helfen mit einen Tipp oder einen Beispiel.

[F3K Total]

Hi,
versuche es mal damit

Code: Alles auswählen

Sub Savetopdf
    On error goto EH
    Dim myProps(0) as New com.sun.star.beans.PropertyValue
    myProps(0).Name="FilterName"
    myProps(0).Value = "writer_pdf_Export"
    oDoc = ThisComponent
    oTFS = oDoc.getTextFields
    enum = oTFS.createEnumeration
    While enum.hasMoreElements
    oTF = enum.nextElement
    Select Case oTF.TextfieldMaster.Name
    Case "Anrede" : A = oTF.Anchor.String
    Case "Datum" : D = oTF.Anchor.String
    Case "Referentie" : R = oTF.Anchor.String
    End Select
    Wend
    U = "-"
    filename = A & U & D & U & R & U & ".pdf"
    url = ConvertToURL("file:///media/documenten/PDF/" & filename)'Insert Your Desired Directory Path.
    oDoc.StoretoURL(url,myProps)
    oDoc.Modified = false 'avoid Save being called if doc closed without further edits.
    End 'end normal execution.
    EH: 'error handler.
    MsgBox "You may have illegal file name character." & Chr(13)_
    & Chr(13) & filename,,"AN ERROR OCCURRED"
End Sub

Gruß R

[Atwist]

Danke F3K Total,

Klappt wieder und lauft einwandfrei